平面阴影是一种比较特殊的情形。在这种情形里，我们只考虑物体的阴影投射到平面上的情形，所以有一套相对比较简单的专用算法。    
平行光对平面的投影
1.1对平行光投影的考虑
        首先考虑最简单的情况，如何计算一个平行光的投影。平行光在我们的计算中其实就是一个方向矢量，是阴影的投射方向，而平面是阴影要影响的目标物体。我们需要知道到目标物体的Object Space矩阵，在目标物体的空间内将投影物体的顶点进行重新计算，计算其沿光线方向，在阴影接受平面上的位置，这个位置关系可以通过三角形相似来计算。如果我们使用Unity自带的Plane作为阴影接受平面，那么我们只需要重新计算顶点的xz位置，如果阴影投射到Build In的Plane上，那么在其Object Space中，y应该为0，但是实际使用时，为了保证阴影永远在物体上面，我们会对z进行偏移。
        如图所示，一个精准的阴影己经出现在平面上，先展示效果。

1.2进出阴影接受平面的矩阵
    首先，每一个投射平面阴影的物体都需要下面这么一个脚本来告诉它阴影接受物体的信息，
具体来说就是到其Object Space空间的矩阵，以及从平面的Object Space返回的矩阵。

Untiy 3d ShaderLab平面阴影(一)

 Untiy 3d ShaderLab平面阴影(一)Untiy 3d ShaderLab平面阴影(一)
using UnityEngine;  
using System.Collections;  
[ExecuteInEditMode]  
public class PlaneShadowCaster : MonoBehaviour {  
    public Transform reciever;  
    void Update () {  
        GetComponent().sharedMaterial.SetMatrix("_World2Ground",reciever.GetComponent().worldToLocalMatrix);  
        GetComponent().sharedMaterial.SetMatrix("_Ground2World", reciever.GetComponent().localToWorldMatrix);  
    }  
}  

1.3使用三角形相似计算阴影
    知道如何出入阴影接受平面的矩阵后，我们就可以对一个投射阴影的物体计算阴影了。这是在PlanarShadow  l.shader中完成的，

其完全代码如下:

 Untiy 3d ShaderLab平面阴影(一)Untiy 3d ShaderLab平面阴影(一)
Shader "Tut/Shadow/PlanarShadow_1" {  
    SubShader {  
    pass {  //对物体本身做一个简单的光照计算      
        Tags { "LightMode" = "ForwardBase" }  
        Material{Diffuse(1,1,1,1)}  
        Lighting On  
    }  
    pass {     
        Tags { "LightMode" = "ForwardBase" }   
        Blend DstColor SrcColor  
        Offset -1,-1//使阴影在平面之上  
        CGPROGRAM  
        #pragma vertex vert   
        #pragma fragment frag  
        #include "UnityCG.cginc"  
        float4x4 _World2Ground;  
        float4x4 _Ground2World;  
        float4 vert(float4 vertex: POSITION) : SV_POSITION  
        {  
        float3 litDir;  
            litDir=WorldSpaceLightDir(vertex);   
            litDir=mul(_World2Ground,float4(litDir,0)).xyz;//把光源方向转换到接收平面空间  
            litDir=normalize(litDir);  
        float4 vt;  
            vt= mul(_Object2World, vertex);  
            vt=mul(_World2Ground,vt);//将物体顶点转换到接收平面空间  
        vt.xz=vt.xz-(vt.y/litDir.y)*litDir.xz;//用三角形相似计算沿光源方向投射后的xz  
        vt.y=0;//使阴影保持在接收平面上  
        //vt=mul(vt,_World2Ground);//back to world  
        vt=mul(_Ground2World,vt);//返回到世界坐标空间  
        vt=mul(_World2Object,vt);//计算结果重新表达为Object Space坐标  
        return mul(UNITY_MATRIX_MVP, vt);//经典的MVP变换，输出到Clip Space  
        }  
        float4 frag(void) : COLOR   
        {  
            return float4(0.3,0.3,0.3,1);//一个灰色的阴影出来了  
        }  
        ENDCG   
        }  
   }  
}